本指标整合「强势量价突破」与「低位蓄势启动」双维度逻辑，既保留经典技术形态（量托、多方炮、出水芙蓉、老鸭头等）的可视化标注，又新增 “精准牛股启动” 专属图标信号，通过多条件交叉验证，辅助投资者识别兼具 “强势基因 + 稳健启动特征” 的牛股，适用于 A 股短线 / 波段交易分析。
幅图和选股指标核心定位
融合 “强势量价突破” 与 “低位蓄势启动” 双重逻辑，筛选兼具 “中强势涨幅、多均线突破、趋势向好、量能放大、低位震荡蓄势” 特征的 A 股标的，聚焦短线 / 波段启动阶段的强势股，适用于日线级别选股分析。
核心选股逻辑
指标通过 “强势特征筛选 + 低位启动验证” 双维度交叉过滤，最终输出满足以下全部条件的股票，核心逻辑拆解如下：
第一维度：强势量价特征筛选（BNGE 系列变量）。聚焦 “中强势涨幅 + 多均线突破 + 趋势向好” 的强势基因；
第二维度：低位蓄势启动验证，聚焦 “低位震荡 + 突破新高” 的启动特征，排除高位追涨风险；
最终选股条件：精准牛股启动，精准牛股启动: (完美牛股 OR 主力筹码) AND 放量启动 AND BNGE4≥-0.5 AND VOL>MA(VOL,30)
核心逻辑：同时满足 “强势量价特征” 和 “低位启动特征”，且趋势未走弱、量能放大，双重过滤提升选股精准度。
{主图源码如下}
V5:=MA(VOL,5);
V10:=MA(VOL,10);
V20:=MA(VOL,20);
LDAY1:=BARSLAST(CROSS(V5,V10));
LDAY2:=BARSLAST(CROSS(V5,V20));
LDAY3:=BARSLAST(CROSS(V10,V20));
LTJ1:=(LDAY1>LDAY2 OR LDAY1=LDAY2) {AND COUNT(CROSS(V5,V20),LDAY1)=1} AND LDAY2=0 AND V10<V20;
LTJ2:=(C>O AND REF(C,1)<REF(O,1) AND REF(C,2)>REF(O,2) AND C>REF(C,2));
LTJ:=LTJ1 AND LTJ2;
LTJ0:=LTJ1 AND V10>REF(V10,1);
MA5:MA(C,5),COLORWHITE;
MA10:MA(C,10),COLORCYAN;
MA20:MA(C,20),COLORRED;
MA40:MA(C,40),LINETHICK2,POINTDOT,COLORBLUE;
MA60:MA(C,60),LINETHICK2,POINTDOT,COLORGREEN;
PDAY1 := BARSLAST(CROSS(MA5,MA60));{5日均线上穿60日均线}
PDAY2 := BARSLAST(CROSS(MA10,MA60));{10日均线上穿60日均线，至此形成鸭颈部}
PDAY3 := BARSLAST(REF(HIGH=HHV(HIGH,PDAY2),1));{形成头部，要下跌}
PDAY4 := BARSLAST(CROSS(MA10,MA5){ OR (REF(MA10,1)<REF(MA5,1) AND MA5=MA10)});{下跌后，5日均线和10日均线死叉}
PDAY5 := BARSLAST(CROSS(MA5,MA10){ OR (REF(MA5,1)=REF(MA10,1) AND MA5>MA10)});{回落不久，5日均线和10日均线形成金叉，形成部}
A1:= PDAY1>PDAY2 AND PDAY2>PDAY3 AND PDAY3>PDAY4 AND PDAY4>PDAY5 AND PDAY5<5;
A2:= COUNT(CROSS(MA10,MA5),PDAY2)=1;
A3:=MA5>MA60 AND MA10>MA60;
{JT:=CROSS(MA20,MA60) AND C>O AND REF(C,1)<REF(O,1) AND REF(C,2)>REF(O,2);
CSFR:=CROSS(C,MA20) AND CROSS(C,MA40) AND CROSS(C,MA60);
STICKLINE(JT,H,L,1,0),COLORYELLOW;
STICKLINE(JT,O,C,8,0),COLORYELLOW;
STICKLINE(CSFR,H,L,1,0),COLORWHITE;
STICKLINE(CSFR,O,C,8,0),COLORWHITE;
DRAWTEXT(CSFR,H,'出水芙蓉'),COLORYELLOW;
DRAWTEXT(JT ,L, '价托'),COLORRED;}
CSFR:=CROSS(C,MA20) AND CROSS(C,MA40) AND CROSS(C,MA60);
YDAY1:=BARSLAST(CROSS(MA5,MA10));
YDAY2:=BARSLAST(CROSS(MA5,MA20));
YDAY3:=BARSLAST(CROSS(MA10,MA20));
YJZZ:=(YDAY1=YDAY2 AND YDAY2=YDAY3 OR (YDAY1-YDAY2=1 OR YDAY2-YDAY3=1)) AND REF(MA5,2)<REF(MA10,2) AND REF(MA10,2)<REF(MA20,2) AND MA5>MA10 AND MA10>MA20 ;
YJZZ1:=YDAY1=YDAY2 AND YDAY2=YDAY3 AND MA5>MA10 AND MA10>MA20 AND YDAY1=1;
YJT:=YDAY1>=YDAY2 AND YDAY2=0 AND MA10<MA20;
DAY1:=BARSLAST(CROSS(MA20,MA40));
DAY2:=BARSLAST(CROSS(MA20,MA60));
DAY3:=BARSLAST(CROSS(MA40,MA60));
TJ0:=DAY1>=DAY2 AND DAY3<5;
短顶:MA(REF(HHV(H,40),1),1);
头顶:MA(REF(HHV(H,60),1),1);
年顶:MA(REF(HHV(H,0),1),1),LINETHICK2,POINTDOT,COLORWHITE;
JZZ:=DAY1=DAY2 AND DAY2=DAY3 AND REF(MA20,1)<REF(MA40,1) AND REF(MA40,1)<REF(MA60,1) AND MA20>MA40 AND MA40>MA60;
TJ1:=DAY1>=DAY2 AND COUNT(CROSS(MA20,MA60),DAY1)=1{AND (DAY1-DAY2)<10};
TJ2:=C>O AND CROSS(C,头顶);
TJ21:=C>O AND CROSS(C,短顶);
{TJ22:=C>O AND CROSS(C,年顶) AND VOL<V5;换手率小12%}
TJ3:=VOL>REF(VOL,1);
TJ4:=MA20>MA60 AND MA40>REF(MA40,1) AND MA40<MA60;
TJ5:=DAY1>=DAY2 AND DAY2=0 AND MA40<MA60;
{TJ:=(TJ2 AND TJ3) OR (TJ21 AND TJ3);}
TJ:=DYNAINFO(4)>0
AND HHV(HIGH,10)/LLV(LOW,10)<1.25
AND REF(CLOSE,1)<(LLV(LOW,15)+(HHV(HIGH,15)-LLV(LOW,15))*0.85)
AND CLOSE>OPEN
AND CLOSE>=HHV(HIGH,10);
STICKLINE(LTJ0,H,L,1,0),COLORGREEN;
STICKLINE(LTJ0,O,C,8,0),COLORGREEN;
STICKLINE(TJ,H,L,1,0),COLORRED;
STICKLINE(TJ,O,C,8,0),COLORRED;
{STICKLINE(TJ22,H,L,1,0),COLORYELLOW;
STICKLINE(TJ22,O,C,8,0),COLORYELLOW;}
STICKLINE(LTJ,H,L,1,0),COLORRED;
STICKLINE(LTJ,O,C,8,0),COLORRED;
STICKLINE(CSFR,H,L,1,0),COLORWHITE;
STICKLINE(CSFR,O,C,8,0),COLORWHITE;
DRAWTEXT(CSFR,H,'出水芙蓉'),COLORYELLOW;
DRAWTEXT(TJ,L-0.2, '放量启动'),COLORYELLOW;
{DRAWTEXT(TJ22,H+0.2, '轻松过顶'),COLORWHITE;}
DRAWTEXT(LTJ,H+0.5,'量托+多方炮'),COLORYELLOW;
DRAWTEXT(LTJ0,H+0.5,'量托'),COLORYELLOW;
DRAWTEXT(TJ5,MA60-0.2,'季价托'),COLORYELLOW;
DRAWTEXT(YJT,MA20-0.5,'月价托'),COLORYELLOW;
DRAWTEXT(JZZ,MA60-0.2,'金蜘蛛'),COLORYELLOW;
DRAWTEXT(YJZZ OR YJZZ1,MA20-0.2,'月金蜘蛛'),COLORYELLOW;
老鸭头:=(A1 AND A2 AND A3) AND FILTER(A1 AND A2 AND A3 ,5);
DRAWTEXT(老鸭头,L,'老鸭头'),COLORGREEN;
STICKLINE(老鸭头,H,L,0.5,0),COLORGREEN;
STICKLINE(老鸭头,O,C,6,1),COLORGREEN,LINETHICK3;
{副图源码如下}
BNGE1:=(CLOSE-REF(CLOSE,1))/REF(CLOSE,1)*100;
BNGE2:=BNGE1>=9.85 AND BNGE1<11 AND CLOSE=HIGH;
BNGE3:=EMA(CLOSE,10)-EMA(CLOSE,33);
BNGE4:=BNGE3-EMA(BNGE3,10);
BNGE5:=EMA(CLOSE,13);
BNGE6:=EMA(CLOSE,21);
BNGE7:=(CLOSE+HIGH+LOW)/3;
BNGE8:=EMA(BNGE7,8);
BNGE9:=COUNT(EVERY(BNGE2,5),30);
BNGE10:=CROSS(CLOSE,BNGE8) AND CROSS(CLOSE,BNGE5);
BNGE11:=(CROSS(CLOSE,BNGE5) AND CROSS(CLOSE,BNGE6));
BNGE12:=LOW<=BNGE5 AND LOW<=BNGE8 AND CLOSE>BNGE5;
BNGE13:=BNGE10 OR BNGE11 OR (BNGE12 AND CLOSE>BNGE8) AND BNGE2;
BNGE14:=REF(CROSS(CLOSE,BNGE8),1) AND REF(BNGE1,1)<9;
BNGE15:=CROSS(CLOSE,BNGE8) OR (BNGE14 AND LOW<=BNGE8 AND CLOSE>BNGE8) AND BNGE2;
BNGE16:=CROSS(REF(CLOSE,1),BNGE8) AND REF(BNGE1,1)<9 AND BNGE2;
BNGE17:=(LOW<BNGE6 AND CLOSE>BNGE6 AND BNGE4>=0);
BNGE18:=BNGE11 AND BNGE4>=0 OR BNGE17 AND BNGE2;
BNGE19:=REF(CROSS(C,BNGE5),1) AND REF(CROSS(C,BNGE6),1) AND REF(BNGE1,1)>=7 AND BNGE2;
BNGE20:=COUNT(CROSS(C,BNGE6) AND CROSS(C,BNGE5) AND BNGE1>5 AND BNGE1<9,6)>=1 AND BNGE2;
BNGE21:=LOW<=BNGE6 AND CLOSE>BNGE6 AND BNGE5>BNGE6 AND BNGE2;
BNGE22:=REF(BNGE9,1) AND (CROSS(C,BNGE8) OR CROSS(C,BNGE5)) AND BNGE1>6;
BNGE23:=COUNT(CROSS(BNGE5,BNGE6),2) AND CLOSE>OPEN AND BNGE2;
BNGE24:=COUNT(CROSS(C,BNGE8) AND CROSS(C,BNGE5) AND BNGE1<8,5) AND BNGE2;
牛股量能:=BNGE13 OR BNGE23 OR BNGE24 OR BNGE18 OR BNGE19;
牛股量价:=BNGE22 OR BNGE15 OR BNGE16 AND BNGE8>=BNGE5 AND BNGE5>=BNGE6;
主力筹码:牛股量能 OR BNGE20 OR BNGE21 AND LOW<BNGE6,COLORYELLOW,NODRAW;
完美牛股:牛股量价 AND BNGE4>=0 AND NOT(主力筹码) AND VOL>MA(VOL,50),COLORMAGENTA,NODRAW;
DRAWTEXT_FIX(C>O,0,0.2,0,''),COLORMAGENTA;
STICKLINE(主力筹码,0,1,2,0),COLOR00FFFF;
STICKLINE(完美牛股,0,1,2,0),COLORRED;
DRAWTEXT(完美牛股,0.8,' ≮完美牛股≯'),COLORYELLOW;
