指标是一个综合信息显示与趋势分析工具。
核心功能：
1. 信息面板：在K线图固定位置显示股票所属行业、概念、地域板块、流通市值、流通盘、机构评级、策略标签及实际控制人信息。
2. K线增强：
绘制K线。
对涨停、跌停K线进行特殊颜色标识。
对“炸板”（即涨停后开板回落）进行标记。
3. 风险与题材提示：在信息面板中标注股票是否属于“近期解禁”、“业绩预升/降”、“风险提示”等特定板块。
4. 趋势分析系统：
计算并绘制由多条均线合成的“持股线”、“加仓线”、“趋势线”和“年线”，用于判断多空趋势。
在“持股线”上穿“趋势线”时显示买入图标。
5. 关键技术位标记：
标记日线MACD在零轴上方首次由红转绿时的高点，并绘制水平压力线。
自动寻找最近60个交易日内的前高，并绘制水平支撑线及标注价格。
6. 动态标记：
当“大单动向”指标数值大于1时，在K线下方显示“大单”字样。
当“换手率”超过50%时，加粗显示“持股线”。
使用要点：
指标将基本面信息、资金动向、关键价量信号与自定义趋势线整合于一幅主图，旨在为投资者提供一个全面的决策参考视图。使用者应重点关注信息面板的提示、K线的特殊标记（涨停/跌停/炸板）、趋势线的多空排列与交叉信号，以及自动划出的支撑/压力位。
{显示基本信息}
流通值:=FINANCE(46)*C/100000000;
所属板块:=STRCAT(STRCAT(' [●]：',HYBLOCK),STRCAT(STRCAT(' [●]：',GNBLOCK),STRCAT(STRCAT(' [●]：',DYBLOCK),STRCAT(STRCAT(STRCAT(' 市值Z: ',CON2STR(流通值,2)),'亿'),STRCAT(STRCAT(' 流通盘: ',CON2STR(CAPITAL/1000000,2)),'亿')))));
DRAWTEXT_FIX(ISLASTBAR,0,0,0,所属板块),COLORYELLOW;
DRAWTEXT_FIX(1,0.00,0.10,0,STRCAT('机构评级：',EXTERNSTR(1,10017))),COLORYELLOW;
DRAWTEXT_FIX(C>0,0.00,0.05,0,STRCAT('策略：',EXTERNSTR(1,10013))),{COLOR888888;}COLOR00C5FF ;
DRAWTEXT_FIX(C>0,0.20,0.05,0,STRCAT('实际控制：',EXTERNSTR(1,10008))),{COLOR888888;}COLOR00C5FF ;
DIF:=(EMA(C,10)-EMA(C,22));
DEA:=EMA(DIF,8);
MACD1:=2*(DIF-DEA);
DRAWKLINE(H,O,L,C);
{涨跌停变色}
NE:=IF(FINANCE(3)=3 OR FINANCE(3)=4,0.2,0.1);
涨停:=C+0.01>=ZTPRICE(REF(C,1),NE) AND C=H;
ZT:=C/REF(C,1)>1.095 AND H=C;
跌停:=C-0.01<=DTPRICE(REF(C,1),NE) AND C=L;
STICKLINE(涨停,O,HIGH,3,0),COLORFF00FF;
STICKLINE(跌停,LOW,HIGH,3,0),COLORYELLOW;
{大单DDX}
大单动向:=(LARGEINTRDVOL-LARGEOUTTRDVOL)*10000/FINANCE(46);
DRAWTEXT(大单动向>1,L*1.02,'大单'),COLORYELLOW;
{炸板标识}
KCBB:=IF(CODELIKE('68') OR CODELIKE('30'),1,0);
ZF0:=IF(KCBB=1,1.195,1.095);
炸板1:=H>REF(C,1)*ZF0 AND C<H;
涨停10:=C>REF(C,1)*ZF0;
炸板2:=IF(炸板1 AND NOT(涨停10),1,0);
LX11:=BARSLAST(炸板2>0);
炸板3:IF(炸板1 AND NOT(涨停10),H*1,DRAWNULL),POINTDOT,COLORFF00FF,LINETHICK9;
DRAWTEXT_FIX(INBLOCK('近期解禁'),0,0.28,0,'近期解禁')COLORYELLOW;
DRAWTEXT_FIX(INBLOCK('拟减持'),0.07,0.28,0,'拟减持')COLORYELLOW;
DRAWTEXT_FIX(INBLOCK('连续亏损'),0.14,0.28,0,'连续亏损')COLORYELLOW;
DRAWTEXT_FIX(INBLOCK('高管减持'),0.21,0.28,0,'高管减持')COLORYELLOW;
DRAWTEXT_FIX(INBLOCK('业绩预升'),0.28,0.28,0,'业绩预升')COLORRED;
DRAWTEXT_FIX(INBLOCK('业绩预降'),0.35,0.28,0,'业绩预降')COLORGREEN;
DRAWTEXT_FIX(INBLOCK('商誉减值'),0.42,0.28,0,'商誉减值')COLORGREEN;
DRAWTEXT_FIX(INBLOCK('股东减持'),0.49,0.28,0,'股东减持')COLORGREEN;
DRAWTEXT_FIX(INBLOCK('风险提示'),0.56,0.28,0,'风险提示')COLORGREEN;
持股线:(EMA(CLOSE,3)+EMA(CLOSE,5)+EMA(CLOSE,10)+EMA(CLOSE,20))/4,COLORCYAN;
加仓线:EMA(持股线,10),LINETHICK1,COLORRED;
趋势线:EMA(持股线,20),LINETHICK1,COLORFF00FF;
DRAWICON(CROSS(持股线,趋势线),趋势线,34);
年线:MA(C,250),LINETHICK3,COLORRED;
{日MACD红翻绿划线}
TT:=BARSLAST(MACD1<0 AND REF(MACD1,1)>0 AND MIN(DIF,DEA)>0),NODRAW;
HH:REF(H,TT),COLORYELLOW,NODRAW;
STICKLINE(BACKSET(ISLASTBAR,BARSLAST(TT)+TT+1),HH,HH*1.003,2.5,0),COLORGREEN;
{60日前高划线}
LT:=LLVBARS(L,60);
LTT:=BARSLAST(CURRBARSCOUNT=CONST(LT)+1);
HT:=FINDHIGHBARS(H,LT+1,60,1);
EXT1:DRAWLINE(CURRBARSCOUNT=CONST(HT)+1,H,ISLASTBAR,REF(H,HT),0),COLOR7CAE39,LINETHICK1,DOTLINE;
TT1:=BARSLAST(CURRBARSCOUNT=CONST(HT)+1);
DRAWTEXT(TT1=0,REF(H,TT1)*1.03,VARCAT(VARCAT('撑：',VAR2STR(REF(H,TT1),2)),'元'))COLOR7CAE39;
换手率Z:=V*10000/FINANCE(46),COLORCYAN,LINETHICK1;
IF(换手率Z>=50,持股线,DRAWNULL),LINETHICK2,COLORBLUE;
