通达信〖量学九阴真经〗完全遵照王子量学原理编写指标源码
这套“量学九阴真经”，是我多年实盘一直在用的工具，编写完全遵照王子量学原理。
看盘时：青色K线作为减仓参考；黄色K线代表涨停；带枚红芯的K线，表示曾经涨停。
源码公开，其他细节不赘述。懂量学的人自然知道其含金量；没接触过量学的，就不必下载了。
{涨跌信号}
是否显示信号:=1;
ZT:=(CLOSE>=ZTPRICE(REF(CLOSE,1),0.1)); { 以涨停收盘 };
ZT1:=IF(PERIOD=5,ZT,DRAWNULL);
DT:=(CLOSE<=DTPRICE(REF(CLOSE,1),0.1)); { 以跌停收盘 };
DT1:=IF(PERIOD=5,DT,DRAWNULL);
STICKLINE(ZT1,O,C,2.9,0),COLORYELLOW;
STICKLINE(DT1,O,C,2.9,0),COLORGREEN;
涨幅:=(C-REF(C,1))/REF(C,1)*100,NODRAW;
最高涨%:=(H-REF(C,1))/REF(C,1)*100,COLOR0000FF,NODRAW;
CZT:=最高涨%>=9.91 AND 涨幅<9.91;
CZT1:=IF(PERIOD=5,CZT,DRAWNULL);
STICKLINE(CZT1,C,(C+O)/2,0.5,0),COLOR4080FF;
{阳胜进，阴胜出}
阴线:=C<REF(C,1);
阴距:=BARSLAST(阴线),NODRAW;
阳线:=C>REF(C,1) ;
阳距:=BARSLAST(阳线),NODRAW;
双阳:=COUNT(阳线,2)=2;
双阴:=COUNT(阴线,2)=2;
阳双胜:=阳线 AND VOL>REF(VOL,阴距)*0.9 AND C>REF(O,阴距);
阳量积阴胜:=双阳 AND (V+REF(V,1))>REF(V,2) AND C>REF(O,阴距);
阴双胜:=阴线 AND VOL>REF(VOL,阳距)*0.85 AND C<REF(O,阳距);
阴量积阳胜:=双阴 AND (V+REF(V,1))>REF(V,2) AND C<REF(O,阳距);
阳胜A:=阳双胜 OR 阳量积阴胜;
阴胜A:=阴双胜 OR 阴量积阳胜;
阳胜距:=BARSLAST(阳胜A),NODRAW;
阴胜距:=BARSLAST(阴胜A),NODRAW;
阳胜:=REF(阳胜距>阴胜距,1)=1 AND 阳胜A;
阳胜1:=IF(PERIOD=5 AND 是否显示信号,阳胜,DRAWNULL);
阴胜:=REF(阴胜距>阳胜距,1)=1 AND 阴胜A;
阴胜1:=IF(PERIOD=5 AND 是否显示信号,阴胜,DRAWNULL);
DRAWICON(CURRBARSCOUNT<100 AND 阳胜1,L,42);
DRAWICON(CURRBARSCOUNT<100 AND 阴胜1,H*1.01,43);
{九阴真经}
阴盖阳:=REF(C,1)>REF(O,1) AND C<O AND ((O-C)>REF(C,1)-REF(O,1)) AND C<REF(C,1),COLORCYAN,NODRAW;
双阴露:=REF(C,1)<REF(O,1) AND C<O AND C<REF(C,1),COLORMAGENTA,NODRAW;
跳空阴:=C<O AND O<REF(L,1) AND H<REF(L,1),COLORGREEN,NODRAW;
YGYJ1:=REF(C,1)>REF(O,1) AND REF(C,1)>REF(C,2) AND C<O AND H>REF(H,1) AND (L<REF(L,1) OR L=REF(L,1));
阴过阳:=YGYJ1 AND VOL>REF(VOL,1),COLORYELLOW,NODRAW;
YBYJ1:=REF(C,1)>REF(O,1) AND C<O AND C<REF(C,1);
阴并阳:=YBYJ1 AND VOL<REF(VOL,1)*1.03 AND VOL>REF(VOL,1)*0.98,COLORWHITE,NODRAW;
BLYJ1:=REF(C,1)>REF(O,1) AND C<O AND C<REF(C,1);
倍量阴:=BLYJ1 AND VOL>REF(VOL,1)*1.9,COLORRED,NODRAW;
阴胜出:=C<REF(C,1) AND REF(C,1)>REF(C,2) AND VOL>REF(VOL,1),COLORYELLOW,NODRAW;
蓝:=阴盖阳 OR 双阴露 OR 跳空阴 OR 阴过阳 OR 阴并阳 OR 倍量阴 OR 阴胜出;
减仓:=IF(PERIOD=5 AND 是否显示信号,蓝 AND NOT(阳胜距>阴胜距=1),DRAWNULL),COLORCYAN,NODRAW;
STICKLINE(CURRBARSCOUNT<100 AND 减仓,O,C,0.5,0),COLOR808040;
未来函数检测结果如下：
该公式没有未来函数
是否显示信号赋值:1
ZT赋值:(收盘价>=计算涨停价)
ZT1赋值:如果周期类型=5,返回ZT,否则返回无效数
DT赋值:(收盘价<=计算跌停价)
DT1赋值:如果周期类型=5,返回DT,否则返回无效数
当满足条件ZT1时,在开盘价和收盘价位置之间画柱状线,宽度为2.9,0不为0则画空心柱.,画黄色
当满足条件DT1时,在开盘价和收盘价位置之间画柱状线,宽度为2.9,0不为0则画空心柱.,画绿色
涨幅赋值:(收盘价-1日前的收盘价)/1日前的收盘价*100,NODRAW
最高涨%赋值:(最高价-1日前的收盘价)/1日前的收盘价*100,COLOR0000FF,NODRAW
CZT赋值:最高涨%>=9.91 AND 涨幅<9.91
CZT1赋值:如果周期类型=5,返回CZT,否则返回无效数
当满足条件CZT1时,在收盘价和(收盘价+开盘价)/2位置之间画柱状线,宽度为0.5,0不为0则画空心柱.,COLOR4080FF
阴线赋值:收盘价<1日前的收盘价
阴距赋值:上次阴线距今天数,NODRAW
阳线赋值:收盘价>1日前的收盘价
阳距赋值:上次阳线距今天数,NODRAW
双阳赋值:统计2日中满足阳线的天数=2
双阴赋值:统计2日中满足阴线的天数=2
阳双胜赋值:阳线 AND 成交量(手)>阴距日前的成交量(手)*0.9 AND 收盘价>阴距日前的开盘价
阳量积阴胜赋值:双阳 AND (成交量(手)+1日前的成交量(手))>2日前的成交量(手) AND 收盘价>阴距日前的开盘价
阴双胜赋值:阴线 AND 成交量(手)>阳距日前的成交量(手)*0.85 AND 收盘价<阳距日前的开盘价
阴量积阳胜赋值:双阴 AND (成交量(手)+1日前的成交量(手))>2日前的成交量(手) AND 收盘价<阳距日前的开盘价
阳胜A赋值:阳双胜 OR 阳量积阴胜
阴胜A赋值:阴双胜 OR 阴量积阳胜
阳胜距赋值:上次阳胜A距今天数,NODRAW
阴胜距赋值:上次阴胜A距今天数,NODRAW
阳胜赋值:1日前的阳胜距>阴胜距=1 AND 阳胜A
阳胜1赋值:如果周期类型=5AND是否显示信号,返回阳胜,否则返回无效数
阴胜赋值:1日前的阴胜距>阳胜距=1 AND 阴胜A
阴胜1赋值:如果周期类型=5AND是否显示信号,返回阴胜,否则返回无效数
当满足条件到最后交易的周期<100AND阳胜1时,在最低价位置画42号图标
当满足条件到最后交易的周期<100AND阴胜1时,在最高价*1.01位置画43号图标
阴盖阳赋值:1日前的收盘价>1日前的开盘价 AND 收阴线AND ((开盘价-收盘价)>1日前的收盘价-1日前的开盘价) AND 收盘价<1日前的收盘价,画青色,NODRAW
双阴露赋值:1日前的收盘价<1日前的开盘价 AND 收阴线AND 收盘价<1日前的收盘价,画洋红色,NODRAW
跳空阴赋值:收阴线AND 开盘价<1日前的最低价 AND 最高价<1日前的最低价,画绿色,NODRAW
YGYJ1赋值:1日前的收盘价>1日前的开盘价 AND 1日前的收盘价>2日前的收盘价 AND 收阴线AND 最高价>1日前的最高价 AND (最低价<1日前的最低价 OR 最低价=1日前的最低价)
阴过阳赋值:YGYJ1 AND 成交量(手)>1日前的成交量(手),画黄色,NODRAW
YBYJ1赋值:1日前的收盘价>1日前的开盘价 AND 收阴线AND 收盘价<1日前的收盘价
阴并阳赋值:YBYJ1 AND 成交量(手)<1日前的成交量(手)*1.03 AND 成交量(手)>1日前的成交量(手)*0.98,画白色,NODRAW
BLYJ1赋值:1日前的收盘价>1日前的开盘价 AND 收阴线AND 收盘价<1日前的收盘价
倍量阴赋值:BLYJ1 AND 成交量(手)>1日前的成交量(手)*1.9,画红色,NODRAW
阴胜出赋值:收盘价<1日前的收盘价 AND 1日前的收盘价>2日前的收盘价 AND 成交量(手)>1日前的成交量(手),画黄色,NODRAW
蓝赋值:阴盖阳 OR 双阴露 OR 跳空阴 OR 阴过阳 OR 阴并阳 OR 倍量阴 OR 阴胜出
减仓赋值:如果周期类型=5AND是否显示信号,返回蓝ANDNOT(阳胜距>阴胜距=1),否则返回无效数,画青色,NODRAW
当满足条件到最后交易的周期<100AND减仓时,在开盘价和收盘价位置之间画柱状线,宽度为0.5,0不为0则画空心柱.,COLOR808040
